Rumus Excel IF Bertingkat, Sederhana, Gabungan OR AND, dan Konversi

260

A. Dasar Rumus Excel IF

Rumus Excel IF adalah fungsi (function) yang digunakan untuk menampilkan suatu nilai (output) berupa TRUE atau FALSE dengan melakukan uji pemenuhan kondisi-kondisi yang ada terhadap sel atau range tertentu. Output TRUE apabila data memenuhi kondisi yang ada, sedangkan output FALSE apabila data tidak memenuhi kondisi yang ada. Rumus Excel IF merupakan salah satu penerapan dari Computing Intelligence menggunakan operasi logika matematika. Sebelum mempelajari rumus Excel IF bertingkat, perlu diketahui sistematika dasar formula IF.

Artikel terkait: Rumus Fungsi TRUE dan FALSE pada Excel beserta Contoh

=IF(logical_test, [value_if_true], [value_if_false])
  1. logical test adalah ekspresi logika yang diujikan dengan data bersangkutan.
  2. [value_if_true] adalah output yang ditampilkan ketika data memenuhi logical_test (true). Nilai variabel ini dapat ditulis dengan tanda "petik".
  3. [value_if_false] adalah output yang ditampilkan ketika data tidak memenuhi logical_test (false). Nilai variabel ini dapat ditulis dengan tanda "petik".
  4. Jika [value_if_true] atau [values_if_false] dikosongkan, maka output default yang ditampilkan adalah teks TRUE atau FALSE.

PENTING: Penggunaan koma (,) atau semicolon (;) dalam FORMULA disesuaikan dengan versi Microsoft Excel dan konfigurasi bahasa pada komputer anda.

Berikut beberapa operasi logika dan aritmatika yang dapat digunakan, untuk penjelasan mengenai operasi logika yang lebih lengkap anda dapat membaca artikel "Cara Membuat Operasi Logika Pada Excel".

Simbol  Fungsi
 +  Penjumlahan
 –  Pengurangan
 *  Perkalian
 /  Pembagian
 %  Persen
 ^  Perpangkatan
 =  Sama dengan
 <  Kurang dari
 <=  Kurang dari atau sama dengan
 >  Lebih dari
 >=  Lebih dari sama dengan
 <>  Tidak sama dengan

Dari sistematika diatas dapat dibuat formula Excel IF sederhana atau tunggal dan bertingkat atau majemuk.


B. Rumus Excel IF Sederhana/Tunggal

Rumus Excel IF Tunggal hanya memuat satu operasi logika dengan output pasangan tunggal. Misalkan diketahui nilai praktikum Microsoft Excel 10 siswa adalah 60, 75, 85, 79, 90, 45, 77, 68, 90, 50. Akan ditentukan siswa yang lulus praktikum harus mencapai nilai 76 dengan menggunakan Microsoft Excel. sehingga dapat digunakan formula berikut dengan teknik Autofill.

PENTING: Penggunaan koma (,) atau semicolon (;) dalam FORMULA disesuaikan dengan versi Microsoft Excel dan konfigurasi bahasa pada komputer anda.

Baca Juga: Cara Menggunakan Autofill pada Excel

=IF(sel_nilai>=76,"LULUS","TIDAK LULUS")

Cara Menggunakan IF Pada Excel

B1. Rumus Excel IF AND

Rumus Excel AND digunakan untuk menggabungkan dua atau lebih operasi logika dengan nilai kebenaran benar saat semua operasi logika terpenuhi. Berikut sistematika formula AND pada Excel.

=AND(logical1, [logical2], [logical2],...)

Anda dapat menggunakan 255 operasi logika menggunakan fungsi IF pada Microsoft Excel. Fundamental logika AND pada Excel sama dengan teori matematika modern.

  • Saat semua operasi logika bernilai benar/terpenuhi, output yang ditampilkan adalah TRUE.
  • Saat salah satu operasi logika tidak terpenuhi/salah, output yang ditampilkan adalah FALSE. Contoh formula AND dengan 3 syarat
    =AND(A1>0,A1=1,B2<1)

Untuk menggunakan Rumus AND pada IF, anda tinggal memasukkan formula AND sebagai logical_test. Misalkan suatu sanggar akan memilih kandidat perempuan dari 10 orang penari untuk mewakili sanggar tersebut pada olimpiade tari. Pemilihan kandidat harus berumur lebih dari 7 tahun. Berikut dapat digunakan formula Excel untuk kasus ini

=IF(AND(sel_gender="Perempuan",sel_umur>7),"Terpilih","Tidak Terpilih")

Cara Menggunakan IF AND Pada Microsoft Excel

B2. Rumus Excel IF OR

Rumus Excel OR juga digunakan untuk menggabungkan dua atau lebih operasi logika dengan nilai kebenaran salah saat semua operasi logika tidak terpenuhi. Sama halnya dengan AND, anda dapat menggunakan 255 operasi logika dengan formula OR.

=OR(logical1,[logical2],...)
  • Saat salah satu operasi logika terpenuhi, output yang dihasilkan TRUE.
  • Saat semua operasi logika tidak terpenuhi, output bernilai FALSE. Contoh formula OR dengan 2 syarat
    =OR(A2>0,A3=1)

Misalkan akan dihitung bonus penjualan dari 5 orang sales perusahaan kopi pada tabel di bawah. Setiap sales yang datang tepat waktu atau dapat menjual lebih dari target 15 kopi akan mendapat bonus Rp10.000,00. Sales yang datang terlambat dan tidak mampu menjual 15 kopi akan mendapat denda Rp1.000,00 per kopi kurangnya dari target.

=IF(OR(kedatangan="Tepat Waktu",penjualan>=15),10000,(15-penjualan)*1000)

Cara Menggunakan IF OR Pada Microsoft Excel


C. Rumus Excel IF Bertingkat /Majemuk /Nested IF

Rumus IF bertingkat secara umum penggunaannya sama saja dengan IF tunggal. IF bertingkat memanipulasi variabel [value_if_false] sebagai nested IF (percabangan IF).Berikut sistematikanya

PENTING: Penggunaan koma (,) atau semicolon (;) dalam FORMULA disesuaikan dengan versi Microsoft Excel dan konfigurasi bahasa pada komputer anda.

=IF(logical_test1, [value_if_true], logical_test2,[value2_if_true],...,[logical_testN],[valueN_if_true],[valueN_if_false])

Misalkan diketahui pengelompokan nilai mahasiswa yaitu 1 = Kurang, 2 = Cukup, 3 = Baik, dan 4 = Sempurna. Akan dilakukan pengelompokan nilai suatu mata kuliah dari 5 mahasiswa pada tabel berikut.

=IF(nilai=1,"Kurang",IF(nilai=2,"Cukup",IF(nilai=3,"Baik",IF(nilai=4,"Sempurna"))))

Cara Menggunakan IF Bertingkat

Baca juga: Penerapan Fungsi AND pada Rumus IF AND Bertingkat (BAGIAN D)

Anda juga dapat membuat rumus excel IF bertingkat dengan menggunakan gabungan OR dan AND seperti pada langkah formula IF sederhana di atas.


D. Rumus IF Bertingkat dengan Gabungan AND (Kasus: Membuat Konversi Nilai A B C D E)

Jenis kasus IF bertingkat untuk konversi nilai A B C D E merupakan kasus terpopuler, dengan memahaminya pengguna dapat membuat formula yang lebih kompleks. Kasus dasar ini dapat disesuaikan dengan permasalahan yang lebih nyata pada data yang akan dikelola.

Contoh:

Misalkan seorang juri mempunyai kriteria penilaian yaitu:

A untuk 80-100,
B untuk 60-79,
C untuk 40-59,
D untuk 20-39,
E kurang dari 20

Bagaimana juri dapat membuat kriteria penilaian dengan Microsoft Excel?

Penyelesaian:

Sekilas kriteria yang dibuat juri tersebut tidak ada masalah dan dapat diterima secara langsung. Namun apa yang terjadi jika seorang peserta mendapat nilai 79,8?

Nah, kriteria di atas masih ambigu karena hanya bisa diterima untuk angka bulat.

Sehingga juri tersebut harus merevisi kriteria penilaiannya, karena dia beranggapan 79,8 kurang dari 80 maka peserta tersebut mendapat nilai B.

Nah, karena Microsoft Excel merupakan software komputer dan harus didikte untuk mengerjakan suatu hal. Juri tersebut harus membuat kriteria penilaian dalam bentuk logika matematika sederhana (bagian A di atas) berikut:

Ini diselesaikan dengan menggunakan logika AND.

=AND(kriteria bawah, kriteria atas)

Misal sel data awal yang ingin dieksekusi A1

Kriteria Awal Revisi AND
A untuk 80-100, A >= 80 dan A <=100 AND(A1 >= 80, A1 <=100)
B untuk 60-79, B >= 60 dan B < 80 AND(A1 >= 60, A1 <80)
C untuk 40-59, C >= 40 dan C < 60 AND(A1 >= 40, A1 <60)
D untuk 20-39, D >= 20 dan D < 40 AND(A1 >= 20, A1 <40)
E kurang dari 20 E < 20 A1 < 20

Bagaimana formula IF nya?

=IF(AND(A1 >= 80, A1 <=100),"A",IF(AND(A1 >= 60, A1 <80),"B",IF(AND(A1 >= 40, A1 <60),"C",IF(AND(A1 >= 20, A1 <40),"D",IF(A1 < 20,"E","Nilai Salah")))))

PENTING: Penggunaan koma (,) atau semicolon (;) dalam FORMULA disesuaikan dengan versi Microsoft Excel dan konfigurasi bahasa pada komputer anda.

Tutorial lainnya: Daftar Isi Tutorial Excel


Sekian artikel Rumus Excel IF Bertingkat dan Sederhana Serta Gabungan OR AND. Nantikan artikel menarik lainnya dan mohon share dan juga menyukai halaman Advernesia. Terima kasih…

260 KOMENTAR

  1. Rumus untuk membandingkan harga dari data barang gimana ya. contoh
    kita mempunyai data barang PASAR PATOKAN Per KG :
    Cabe merah : 14.000
    Tomat : 7000
    kol : 5.000
    Gula Puith : 12.000
    cabe rawit : 11.000
    --------------------------------------------
    kemudian kita input brang perhari nya cabe merah 15.000
    otomatis harga lagi Mahal. yang saya mau tanyakan bagaimana menandakan barang tersebut sedang naik atau turun harganya, dengan jumlah yang kita inputkan menandakan warna kolom, merah = harga naik, biru = sedang murah.

  2. Selamat pagi gan, mau tanya. Kalo misalnya ada permasalahan kyak gini,
    Jika kode area Ru3 , muatan kurang dari 23 ton harga dikalikan 1000. Jika lebih dari 23 ton dikalikan 1500
    Jika kode area Ru5 muatan kurang dari 23 ton harga dikalikan 1200. Jika lebih dari 23 ton dikalikan 1700
    Jika kode area INT muatan kurang dari 23 ton harga dikalikan 1500. Jika lebih dari 23 ton dikalikan 1800
    Kira-kira pake rumus apa gan, terima kasih dan mohon pencerahannya 🤝

    • Selamat pagi agan Lest...

      Agan dapat menggunakan rumus IF bertingkat,

      =IF(AND(A1="Ru3",B1<23),C1*1000,IF(AND(A1="Ru3",B1>=23),C1*1500,IF(AND(A1="Ru5",B1<23),C1*1200,IF(AND(A1="Ru5",B1>=23),C1*1700,IF(AND(A1="INT",B1<23),C1*1500,IF(AND(A1="INT",B1>=23),C1*1800,"Tidak Ada"))))))

      Namun pada syarat yang agan berikan harus menggunakan kurang (<) dan lebih dari atau sama dengan (>=), sehingga tidak memunculkan error saat berat tepat 23.
      Semoga membantu 🙂

  3. Selamat siang,
    Salam kenal,

    Bisa bantu rumus untuk memindahkan data ke sheet lain dengan mengacu pada 2 kriteria berbeda
    misal, sheet input = inputan data dengan kriteria A dan B dengan beberapa kolom lain yang mengikuti
    dibuat sheet 2 yang isinya semua kriteria A
    dan sheet 3 yang isinya semua kriteria B
    Terima kasih

  4. Tolong dibantu rumusnya
    soal :
    fee marketing keluar jika total penjualan original mencapai >=50.000.000 dan non original >=5.000.000
    fee original 1%*total penjualan
    fee non original 10%*total penjualan
    saya buat rumus seperti dibawah ini,
    =IF(AND(total penjualan>=target),1%*F20,IF(AND(F21>=C21),10%*F21,0))
    belum terjumlah antara original dan non original. kalau ditambah sumif, error

    bagaimana menjumlah fee original dan non original dengan ketentuan pencapaian target diatas

    Terima kasih

    • Saya akan mencoba membantu untuk persoalan kk Wilda Hurriya
      Menggunakan rumus If bertingkat
      =IF(AND(A2>=50000000,B2>=5000000),0.01*A2+0.1*B2,"Belum Keluar")
      A2 adalah original
      B2 adalah non-original
      rumus bisa dimasukkan di baris yang sama misal C2

      Semoga membantu:)

    • Terima kasih pencerahannya,
      setelah saya coba berhasil. namun, jika hanya salah satu yang mencapai target, itu tidak terhitung. yang diminta, salah satu target tercapai pun bisa keluar fee nya

      Terima kasih

    • pakai IF AND gak keluar fee nya kalau salah satu target masuk.
      karena salah satu saja target masuk, fee bisa keluar, saya coba pakai IF OR, dan bisa

      Terima kasih yaaa
      untuk yang menghubungkan data ke sheet lain saya masih belum bisa 🙁

    • Baik kak Wilda, berarti syaratnya bukan "dan" melainkan "atau", Untuk menghubungkan sheet lain... tinggal melakukan penulisan nama sheet pada referensi selnya.. ka 🙂

  5. Saya mau buat penilaian KPI menggunakan kategori
    >100 = A
    100 - 90 = B
    89.9 - 75 = C
    74.9 - 60 = D
    < 60 = E

    Ini jadi gimana ya rumusnya bingung mas. thanks

    • Halo mas Rizki Kesuma dari KPI, anda dapat menggunakan rumsu if beringkat dengan gabungan AND-
      =IF(A2>100,"B",IF(AND(A2<=100,A2>=90),"B",IF(AND(A2<90,A2>=75),"C",IF(AND(A2<75,A2>=60),"D","E"))))

      Semoga membantu tugasnya 🙂

  6. mohon bantuannya gan.
    bagaimana jika kolom B bernilai dan syarat kriterianya jika kolom B=1.1 jawabnya OR, maka isian kolom C-nya menjadi
    B1 0.5 C1 OB dari isian ini kolom B saya ingin merubahnya menjadi C1 OB
    B2 0.7 C2 OB C2 OB
    B3 1.1 C3 OR C3 OR
    B4 1.3 C4 OR C4 OR
    B5 0.9 C5 OB C5 WT
    B6 1.0 C6 OB C6 WT
    B7 1.3 C7 OR C7 OR
    B8 1.4 C8 OR C8 OR
    B9 0.8 C9 OB C9 BR
    B10 0.6 C10 OB C10 BR
    dengan penjelasan WT berasal jika isi OB berada ditengah OR dan BR jika berada dibawah OR dan tdk ada lgi yg dibawahnya.
    dan isian tersebut dibatasi oleh kolom A,misal A1-A10 (pisang), A11-A25 (mangga), sehingga rumus diatas akan berulang lgi setiap masuk pada kategori baru dalam kolom A.

    Terima kasih

    • mohon bantuannya gan.
      bagaimana jika kolom B bernilai dan syarat kriterianya jika kolom B>=1.1 jawabnya OR, jika kolom B<1.1 jawabnya OB maka isian kolom C-nya menjadi
      B1 0.5 C1 OB dari isian ini kolom B saya ingin merubahnya menjadi C1 OB
      B2 0.7 C2 OB C2 OB
      B3 1.1 C3 OR C3 OR
      B4 1.3 C4 OR C4 OR
      B5 0.9 C5 OB C5 WT
      B6 1.0 C6 OB C6 WT
      B7 1.3 C7 OR C7 OR
      B8 1.4 C8 OR C8 OR
      B9 0.8 C9 OB C9 BR
      B10 0.6 C10 OB C10 BR
      dengan penjelasan WT berasal jika isi OB berada ditengah OR dan BR jika berada dibawah OR dan tdk ada lgi yg dibawahnya.
      dan isian tersebut dibatasi oleh kolom A,misal A1-A10 (pisang), A11-A25 (mangga), sehingga rumus diatas akan berulang lgi setiap masuk pada kategori baru dalam kolom A

  7. Hallo kakak mau tanya bagaimana rumus IF nya : jika barang B adalah barang yang termasuk dalam 25 Top sku, maka B dikali 1,5 jika tidak B dikali 1 seperti apa ya?
    Terimakasih.

    • Hallo Kakak Herlambang, mohon maaf sebelumnya karena slow respon
      Kakak bias menggunakan rumus IF biasa untuk menyelesaikannya

      =IF(A2="25 Top sku",B2*1.5,B)

      A2 adalah jenis barang
      B2 adalah nilai barang
      C2 adalah tempat formula dimasukkan

      Semoga bermanfaat 🙂

  8. Hallo kakak,

    bantu dong rumus ini;
    Stock A quantity 5, minimum stock A adalah 2 dan maksimum stock A adalah 3.
    bagaimana rumusnya : jika stock A lebih besar dari maksimum , maka excess dan quantitiy excessnya adalah 5-3
    Terima kasih

    • Hallo juga Kakak Iwan,
      Mohon maaf atas slow responnya,
      Kakak dapat menggunakan rumus berikut

      =IF(A1>3,A1-3, "Jumlah Normal atau Kurang")

      Semoga membantu

  9. hai kak, bagaimana soalnya seperti ini :
    Diberikan sebesar 10%dari biaya kursus untuk siswa yang tanggal masuknya kurang dari tanggal proses dan uang mukanya lebih besar dari biasa kursus, selain itu tidak dapat diskon.

    • Hai juga Kakak Eva,
      Mohon maaf untuk slow responnya,
      Kakak bias menggunakan rumus berikut
      =IF(AND(A1100000),C1-(0.1*C1),C1)

      A1 = Tanggal Daftar,
      B1 = Uang Muka,
      C1 = Total Bayar,

      Semoga membantu 🙂

  10. Malam, maaf bagaimana rumus untuk
    A. B. C
    Kode. Jenis. Jumlah
    1 D123. Ao1. 5
    2 A222. Ao2. 10
    3 D123 Ao1. 5
    4. D123 Ao2. 10

    Jika A1 = A2 dan b1=b2 maka c1+c2 kalau tidak maka hasil nya tetap, mhon bantuannya mkasih

    • Selamat malam, Kakak Irma...
      Mohon maaf atas slow responnya, kakak dapat menggunakan rumus berikut

      =IF(AND(A1=A2,B1=B2), C1+C2, C1)

      Semoga dapat membantu 🙂

  11. Halo selamat Siang mau konsultasi untuk IF bertingkat. IF(AND(sel_gender="Perempuan",sel_umur>7)"Terpilih","Tidak Terpilih"))
    jika saya ada data lagi
    IF(AND(sel_gender="Perempuan",sel_umur>7)"Terpilih","Tidak Terpilih");IF(AND(sel_gender="Laki",sel_umur>7)"Tidak terpilih","")
    IF(AND(sel_gender="TIdak diketahi",sel_umur>7)"Tidak Terpilih","")))

    apakah bisa jalan formula IF AND Bertingkat macam itu?? saya ada kasus seperti itu belum ketemu solusinya

    • Selamat sore kakak Jeje,

      Jika outputnya hanya "Terpilih" dan "Tidak perpilih", cukup menggunakan
      =IF(AND(sel_gender="Perempuan",sel_umur>7)"Terpilih","Tidak Terpilih"))

      Jika ada output yang berbeda, kakak cukup mengganti [value_if_false] menjadi if bertingkat,
      Semoga membantu 🙂

    • Selamat malam kak Yulian, untuk membuat deskripsi nilai siswa dapat menggunakan formula sederhana seperti tutorial ini. Sebelumnya kurikulum apa yang kakak Yulian inginkan?
      Secepatnya akan saya usahakan buat artikelnya…

  12. mantab tutorialnya .
    mohon dibantu nih, saya sudah coba if bertingkat di tutorial masih belum ketemu.
    # misal nilai patokan 80
    jika nilai x1=100 maka disebut istimewa
    jika nilai x2=90 maka disebut Bagus sekali
    jika nilai x3=80 maka disebut bagus
    jika nilai x4=70 maka kurang
    jika nilai x5<=60 maka mengulang

    mohon bantuannya
    terima kasih

    • Terima kasih kak Zainal, untuk membuat if bertingkat berfungsi dengan lebih baik. Sebaiknya semua fungsi logikanya dalam bentuk interval, x <=100, x <= 90, dst. Apakah maksud kakak seperti itu?

    • =IF(A2<=60,"Mengulang",(IF(AND(A2>60,A2<=70),"Kurang",IF(AND(A2>70,A2<=80),"Bagus",IF(AND(A2>80,A2<=90),"Bagus Sekali",IF(AND(A2>90,A2<=100),"Istimewa","Nilai Melebihi Batas"))))))

  13. Bagus sekali tutorialnya.
    Tapi saya kebingungan soal rumus IF jika menggunakan waktu. Dalam hal ini saya punya data sebagai berikut:
    >6:16 (lebih dari 6 menit 16 detik) maka nilainya 1
    6:00-6:15 (6 menit - 6 menit 15 detik) maka nilainya 2
    5:31-5:59 ( 5 menit 31 detik - 5 menit 59 detik) maka nilainya 3
    < 5:30 (kurang dari 5 menit 30 detik) maka nilainya 4
    Bagaimana ya rumusnya?

    • Terima kasih atas komentarnya kakak Mursyid,
      Mohon maaf jika balasannya lambat.
      Data yang diuji harus dalam bentuk fungsi TIME, misalnya A1=TIME(0,6,20)
      Kemudian dalam fungsi IF logical expression memuat fungsi time yang dikonversi

      missal
      = IF(CONVERT(C1,"mn","sec") > CONVERT(TIME(0,6,16),"mn","sec"), "Nilai 1", "Lainnya")

      Semoga membantu pekerjaannya kak, saya usahakan akan membuat tutorial ini secepatnya 🙂

  14. Saya mau buat range penilaian dengan kategori berikut :
    >100 = Cek Kembali
    = 100 (sama dengan 100) = Oke
    80,1 – 99,9 = Baik
    70,1 – 80 = Cukup
    60,1 - 70 = Kurang
    50,1 - 60 = Sangat Kurang
    < 50 = Perhatian Khusus

    Ini jadi gimana ya rumusnya. mohon pencerahan. thanks b4

    • Terima kasih atas komentarnya kakak

      =IF(A1>100,"Cek Kembali",IF(A1=100,"Oke",IF(AND(A1<100,A1>80),"Baik",IF(AND(A1<=80,A1>70),"Cukup",IF(AND(A1<=70,A1>60),"Kurang",IF(AND(A1<=60,A1>50),"Sangat Kurang",IF(A1<=50,"Perhatian Khusus","Invalid")))))))

      Semoga bermanfaat :)

  15. Min mau tanya, kalo kondisinya :
    *jika harga > 8 juta atau lama kredit > 10 bulan maka hadiah central lock
    *jika harga > 4 juta atau lama kredit > 6 bulan makan hadiah kipas angin
    *salain ketentuan di atas hadiah jas hujan
    Gimana ya fungsu if nya?

    • Terima kasih kakak Fitri…

      =IF(OR(A2>8000000,B2>10),"Central Lock",IF(OR(A2>4000000,B2>6),"Kipas Angin","Jas Hujan"))

      Dengan A2 = Harga, B2 = kredit
      Semoga bermanfaat 🙂

  16. Mas Saya mau tanya,
    Rumus excel untuk pengurangan Stok tiap item yang berbeda dengan penggolongan / pengelompokan seperti apa ?
    Contoh :
    Transaksi tanggal 3-10-18 stok awal 4 pallet
    Transaksi tanggal 4-10-18 keluar 1 pallet
    -1 pallet berisi 1 tutup, 1 alas, 2 samping

    Mohon bantuannya mas...

    • Terima kasih kakak Juyyin, kakak bias menggunakan rumus SUMIF untuk melakukannya,

      Misalnya stok = Jumlah Stok A - SUMIF(range nama stok keluar, =nama stok, jumlah keluar)
      Artikel terkait SUMIFS
      Semoga dapat membantu pekerjaannya 🙂

1 2 3 4 6

AYO BERKOMENTAR

Tulis komentar
Masukkan nama Anda